Show text box over image (PPT2000 SP3)

Topic

New Reply

I would be grateful for some help. I have a presentation of some 120 slides two-thirds of which are images the same size as the slide. Temporarily while completing the presentation I want to seperately display the slide number & the image number (they are different) over the images.

In the footer I have implemented the include slide number facility but because of the above-mentioned full-size images is only seen on one-third of the slides. Is it possible to have the slide number appear over an image?

I have inserted a text box on the Master Slide & set its order to the front but it does not appear over the images. Can a text box be displayed over an image? If so how?

Reply | Quote

Replies

Since your pictures cover the entire slide, you would have to create a text box on each page. Here is a macro to do just that. I have also attached a sample presentation with the code and instructions. You will have to save the attachment on your hard drive and open it in PowerPoint to run the macros. HTH –Sam

Option Explicit

Public Sub deletePageBoxes()
Dim i As Long, s As Shape
    With ActivePresentation.Slides
        For i = 1 To .Count
            For Each s In .Item(i).Shapes
                If s.Name = "TextPage" Then s.Delete
            Next s
        Next i
    End With
End Sub

Public Sub createPageBoxes()
Dim i As Long, j As Long, s As String
    deletePageBoxes
    With ActivePresentation.Slides
        j = 0
        For i = 1 To .Count
            If hasPicture(.Item(i)) Then
                j = j + 1
                s = "sld " & i & ", pic " & j
            Else
                s = "sld " & i
            End If
            With .Item(i).Shapes
                With .AddTextbox(msoTextOrientationHorizontal, 580#, 498#, 120#, 24#)
                    .Name = "TextPage"
                    .TextFrame.TextRange.Text = s
                    .TextFrame.TextRange.Font.Size = 14
                    .Fill.ForeColor.SchemeColor = ppBackground
                    .Fill.Visible = msoTrue
                End With
            End With
        Next i
    End With
End Sub

Private Function hasPicture(sld As Slide) As Boolean
    Dim s As Shape
    For Each s In sld.Shapes
        If Left(s.Name, 7) = "Picture" Then
            hasPicture = True
            Exit Function
        End If
    Next s
    hasPicture = False
End Function

Reply | Quote

Sam my thanks for your help – way beyond my expectations!

Reply | Quote