More help with recorded macros

Topic

New Reply

Folks,
Right now with the first 3 of an expected 150 two-page tables (to be done by this Friday), I am selecting the topic rows by clicking in the left margin while holding down Ctrl. I then apply the shading macro I recorded. Naturally, I”m looking for a way to skip or reduce about 20 keystrokes. I can use Find or the Styles pane to select all white colored text, but I don’t see a way to change the selection from the text to the cell it is in. Also, the recorder doesn’t record select all instances chosen from the in the styles pane or Find In Document (and select all) from the search dialog.

Is it possible to record a macro that selects the white type and then expands the selection to the whole row/cell?

Thanks,
Pam

Reply | Quote

Replies

Something like this maybe?

Code:

Sub ShadeRow()
Selection.HomeKey wdStory
With Selection
    With .Find
        .ClearFormatting
        .Font.Color = wdColorRed
        .Text = ""
        .Replacement.Text = ""
        .Forward = True
        .Wrap = wdFindStop
        .Format = True
        .MatchCase = False
        .MatchWholeWord = False
        .MatchWildcards = False
        .MatchSoundsLike = False
        .MatchAllWordForms = False
    End With
    While .Find.Execute
        .MoveEnd wdRow
        .Shading.ForegroundPatternColor = wdColorGray10
        .Collapse wdCollapseEnd
    Wend
    .Find.ClearFormatting
End With
End Sub

Reply | Quote

Thanks, Jefferson. That should work, just have to switch to my color, which is specified in rgb. I’ll let you know how I make out.

Pam

Reply | Quote

Hi, Jefferson,

The code doesn’t work. The cursor just sits there, and when I open the find dialog, there’s no history of the search. I did change the shading color to rgb. Could that have affected the whole macro?

Pam

Reply | Quote

Maybe the problem is the in find color match. I got a document today which used a shade of green I literally could not figure out a way to “find.”

Reply | Quote

Reveal formatting (Shft F1) is usually a good bet.

Today, I’m getting an error message: Invalid or unqualified reference. And it’s pointing to the “While .Find.Execute” line. If I add “Selection” before .Find, the debug(ger?) says the same thing at the next line. Hmmm. Help.

Reply | Quote

Might be an extra End With somewhere above that line.

Reply | Quote

Jefferson: Thanks for your help. On reading your code, I started thinking of doing the task serially instead of in bulk (the way I do it manually). I recorded a macro to do all the steps once. Then I found a do loop within another macro and put it into mine. Works great.

Thanks again,
Pam

Code:

Sub ShadeHdRows()
‘
‘Mostly recorded
‘
    Selection.Find.ClearFormatting
    Selection.Find.Font.Color = -603914241
    Selection.Find.Replacement.ClearFormatting
    With Selection.Find
        .Text = “”
        .Replacement.Text = “”
        .Forward = True
        .Wrap = wdFindContinue
        .Format = True
        .MatchCase = False
        .MatchWholeWord = False
        .MatchWildcards = False
        .MatchSoundsLike = False
        .MatchAllWordForms = False
    End With
Do
    Selection.Find.Execute
    If Selection.Find.Found = True Then
    Selection.SelectRow
    Selection.Shading.Texture = wdTextureNone
    Selection.Shading.ForegroundPatternColor = wdColorAutomatic
    Selection.Shading.BackgroundPatternColor = 5982208
    Selection.MoveRight Unit:=wdCharacter, Count:=1
Else
    Exit Do
End If
Loop
Selection.Find.ClearFormatting
End Sub

Reply | Quote

I can never work out why Word records the find using a mixture of With Selection.Find and explicitly repeating Selection.Find
This version of your code tidies up the odd way that Word has recorded your steps and also simplifies the loop somewhat

Code:

Sub ShadeHdRows2()  With Selection.Find
    .ClearFormatting
    .Font.Color = 255
    .Replacement.ClearFormatting
    .Text = “”
    .Replacement.Text = “”
    .Forward = True
    .Wrap = wdFindContinue
    .Format = True
    .MatchCase = False
    .MatchWholeWord = False
    .MatchWildcards = False
    .MatchSoundsLike = False
    .MatchAllWordForms = False
    .Execute
    Do While .Found
      Selection.SelectRow
      Selection.Shading.Texture = wdTextureNone
      Selection.Shading.ForegroundPatternColor = wdColorAutomatic
      Selection.Shading.BackgroundPatternColor = 5982208
      Selection.MoveRight Unit:=wdCharacter, Count:=1
      .Execute
    Loop
    .ClearFormatting
  End With
End Sub

Reply | Quote