Minimize App on run (2000)

Topic

New Reply

I am looking for a way to minimize the app window when starting Access. Everything I have tried minimizes the DB window but not the entire app. Is there anyway to do what I’m asking?

Thanks,

Reply | Quote

Replies

Pat,

I don’t know if there is a method built into Access to minimize the whole application, but you can use API calls to do it.

Just have a look at post 228487. It will give you a way to do it with APIs.

Reply | Quote

A very simple way is to use a shortcut to open Access. In the properties of a shortcut, you can specify whether Access starts normal, maximized or minimized.

If you want to do it from Access itself, you need Windows API calls to accomplish it:

1. Create a standard module and copy the following code into it:

Private Type Rect
X1 As Long
Y1 As Long
X2 As Long
Y2 As Long
End Type

Private Type PointAPI
x As Long
y As Long
End Type

Private Type WindowPlacement
Length As Long
Flags As Long
showCmd As Long
ptMinPosition As PointAPI
ptMaxPosition As PointAPI
rcNormalPosition As Rect
End Type

Private Declare Function GetWindowPlacement Lib “user32” _
(ByVal hWnd As Long, lpWndPl As WindowPlacement) As Long

Private Declare Function SetWindowPlacement Lib “user32” _
(ByVal hWnd As Long, lpWndPl As WindowPlacement) As Long

Public Const SW_Maximize = 3
Public Const SW_Minimize = 6
Public Const SW_Restore = 9

Public Function AccessWindow(sw As Long)
Dim wp As WindowPlacement
wp.Length = Len(wp)
GetWindowPlacement Application.hWndAccessApp, wp
wp.showCmd = sw
SetWindowPlacement Application.hWndAccessApp, wp
End Function

2. To minimize the Access application window, call AccessWindow(6), for instance in an AutoExec macro or in the OnLoad event of the startup form of your database (6 = SW_Minimize, but you can’t use a constant in a macro).

Reply | Quote

Thanks! I used a combination of both methods to get my desired results, works great.

Reply | Quote